1. package com.onresolve.jira.groovy.canned.workflow.postfunctions
  3. import com.atlassian.jira.component.ComponentAccessor
  4. import com.atlassian.jira.config.ConstantsManager
  5. import com.atlassian.jira.config.SubTaskManager
  6. import com.atlassian.jira.event.issue.IssueEvent
  7. import com.atlassian.jira.issue.Issue
  8. import com.atlassian.jira.issue.MutableIssue
  9. import com.atlassian.jira.util.ErrorCollection
  10. import com.atlassian.jira.util.SimpleErrorCollection
  11. import com.atlassian.jira.workflow.JiraWorkflow
  12. import com.onresolve.jira.groovy.canned.CannedScript
  13. import com.onresolve.jira.groovy.canned.utils.CannedScriptUtils
  14. import com.onresolve.jira.groovy.canned.utils.ConditionUtils
  15. import com.onresolve.jira.groovy.canned.utils.WorkflowUtils
  16. import com.opensymphony.workflow.loader.ActionDescriptor
  17. import com.opensymphony.workflow.loader.StepDescriptor
  19. class CreateSubTask extends AbstractCloneIssue implements CannedScript{
  21. public static final String FIELD_SUBTASK_SUMMARY = 'FIELD_SUBTASK_SUMMARY'
  22. public static final String FIELD_SUBTASK_ACTION = 'FIELD_SUBTASK_ACTION'
  25. String getName() {
  26. return "Create a sub-task."
  27. }
  29. public String getHelpUrl() {
  30. "https://jamieechlin.atlassian.net/wiki/display/GRV/Built-In+Scripts#Built-InScripts-Createasubtask"
  31. }
  33. String getDescription() {
  34. return "Create a sub-task. Will optionally reopen a matching sub-task."
  35. }
  37. List getCategories() {
  38. ["Function", "Listener"]
  39. }
  41. List getParameters(Map params) {
  42. [
  43. ConditionUtils.getConditionParameter(),
  44. [
  45. Name:FIELD_TARGET_ISSUE_TYPE,
  46. Label:"Target Issue Type",
  47. Type: "list",
  48. Description:"""Target issue type. Leave blank for the same issue type as the source issue.
  49. <br>NOTE: This issue type must be valid for the target project""",
  50. Values: CannedScriptUtils.getAllSubTaskIssueTypes(true),
  51. ],
  52. [
  53. Name:FIELD_SUBTASK_SUMMARY,
  54. Label:"Subtask Summary",
  55. Description:"""Optionally set the summary. If blank it will be inherited from the parent.
  56. <br>This is useful in conjunction with automatic reopening of subtasks""",
  57. ],
  58. super.getOverridesParam(),
  59. [
  60. Name:FIELD_SUBTASK_ACTION,
  61. Label:"Subtask Action",
  62. Type: "list",
  63. Description:"""Optionally set an action that will be applied to a sub-task if a
  64. matching subtask already exists""",
  65. Values: CannedScriptUtils.getAllWorkflowActions(true),
  66. ],
  67. ]
  68. }
  70. public ErrorCollection doValidate(Map params, boolean forPreview) {
  71. SimpleErrorCollection errorCollection = new SimpleErrorCollection()
  72. if (!params[FIELD_TARGET_ISSUE_TYPE]) {
  73. errorCollection.addError(FIELD_TARGET_ISSUE_TYPE, "You must provide the target issue type.")
  74. }
  75. // todo: validation for issue type if set
  77. return errorCollection
  78. }
  80. Map doScript(Map params) {
  81. MutableIssue issue = params['issue'] as MutableIssue
  82. def user = WorkflowUtils.getUser(params)
  83. Boolean doIt = ConditionUtils.processCondition(params[ConditionUtils.FIELD_CONDITION] as String, issue, false, params)
  84. if (! doIt) {
  85. return [:]
  86. }
  88. def String subtaskAction = params[FIELD_SUBTASK_ACTION]
  89. subtaskAction = subtaskAction?.replaceAll(/ .*/, "")
  90. String subtaskSummary = params[FIELD_SUBTASK_SUMMARY]
  91. if (issue.getIssueTypeObject().isSubTask()) {
  92. log.warn ("This issue ($issue) is already a sub-task... doing nothing.")
  93. return [:]
  94. }
  96. // if we have a subtask action, and the subtask exists, and the action is applicable... do it
  97. Collection<MutableIssue> subTasks = issue.getSubTaskObjects()
  98. if (subtaskAction && subtaskSummary && subTasks*.summary.contains(subtaskSummary)) {
  99. subTasks.each {MutableIssue sub ->
  100. if (sub.summary == subtaskSummary) {
  101. if (WorkflowUtils.hasAction(sub, subtaskAction as Integer)) {
  102. try {
  103. // actionIssue(sub, subtaskAction as Integer, WorkflowUtils.getUser(params))
  104. WorkflowUtils.actionIssue(null, sub, subtaskAction as Integer, user, [:])
  105. }
  106. catch (Exception e) {
  107. log.error(e.message, e)
  108. }
  109. }
  110. else {
  111. log.debug("Action not applicable")
  112. }
  113. }
  114. }
  115. return [:]
  116. }
  118. params = super.doScript (params)
  120. Issue newIssue = params['newIssue'] as Issue
  122. def subTaskManager = componentManager.getSubTaskManager()
  124. // get a fresh copy of the issue, otherwise the old version gets indexed by the createSubTaskIssueLink method
  125. // issue = ComponentAccessor.getIssueManager().getIssueObject(issue.id)
  126. subTaskManager.createSubTaskIssueLink(issue, newIssue, user)
  128. params
  129. }
  132. String getDescription(Map params, boolean forPreview) {
  133. ConstantsManager constantsManager = componentManager.getConstantsManager()
  134. StringBuffer sb = new StringBuffer()
  135. sb << getName() + "<br>Subtask will be created with issue type: <b>" +
  136. (params[FIELD_TARGET_ISSUE_TYPE] ? constantsManager.getIssueTypeObject(params[FIELD_TARGET_ISSUE_TYPE] as String)?.name
  137. : "same as parent") + "</b>"
  138. sb.toString()
  139. }
  141. public Boolean isFinalParamsPage(Map params) {
  142. true
  143. }
  144. }