1. 'Registers Google Chrome Portable with Default Programs or Default Apps in Windows
  2. 'chromeportable.vbs - created on May 20, 2019 by Ramesh Srinivasan, Winhelponline.com https://is.gd/dtMxFW
  3. 'Last updated on 3-May-2020 - Added missing sub-keys and more associations. Properly enclosed file name parameter in double-quotes.
  5. Option Explicit
  6. Dim sAction, sAppPath, objFile, oFSO, sbaseKey, sbaseKey2
  7. Dim WshShell : Set WshShell = CreateObject("WScript.Shell")
  8. Dim oFS0 : Set oFSO = CreateObject("Scripting.FileSystemObject")
  10. Set objFile = oFSO.GetFile(WScript.ScriptFullName)
  11. sAppPath = oFSO.GetParentFolderName(objFile)
  12. sAppPath = sAppPath & "\GoogleChromePortable.exe"
  14. If Not oFSO.FileExists (sAppPath) Then WScript.Quit
  15. 'If InStr(" ", sAppPath) <> 0 Then sAppPath = """" & sAppPath & """"
  16. ' Always wrap the directory path in quotes. Fixed on 3-May-2020 by applying one of the methods suggested here https://is.gd/BQR8w8
  17. sAppPath = chr(34) & sAppPath & Chr(34)
  19. ' Uncomment the following line to help with debugging the script - it shows sAppPath in a message box
  20. ' MsgBox "|" & sAppPath& "|"
  22. If WScript.Arguments.Count <> 0 Then
  23. If UCase(Trim(WScript.Arguments(0))) = "-REG" Then Call RegisterChromePortable(sAppPath)
  24. If UCase(Trim(WScript.Arguments(0))) = "-UNREG" Then Call UnregisterChromePortable(sAppPath)
  25. Else
  26. sAction = InputBox("Type REGISTER to add Chrome Portable to Default Apps. Type UNREGISTER to remove.", "Chrome Portable Registration", "REGISTER")
  27. If UCase(Trim(sAction)) = "REGISTER" Then Call RegisterChromePortable(sAppPath)
  28. If UCase(Trim(sAction)) = "UNREGISTER" Then Call UnregisterChromePortable(sAppPath)
  29. End If
  31. Sub RegisterChromePortable(sAppPath)
  32. sbaseKey = "HKCU\Software\"
  33. 'StartmenuInternet i.e. 'sbaseKey2' === 02 of kolbi.cz (https://is.gd/o5yyVp) ===
  34. sbaseKey2 = sbaseKey & "Clients\StartmenuInternet\Google Chrome Portable\"
  36. 'RegisteredApplications === 01 of kolbi.cz (https://is.gd/o5yyVp) ===
  37. WshShell.RegWrite sbaseKey & "RegisteredApplications\Google Chrome Portable", "Software\Clients\StartMenuInternet\Google Chrome Portable\Capabilities", "REG_SZ"
  39. 'Classes === 03 of kolbi.cz (https://is.gd/o5yyVp) ====
  40. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\", "Chrome HTML Document", "REG_SZ"
  41. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\AppUserModelId", "Chrome Portable", "REG_SZ"
  42. 'ChromeHTML\Application - 3-May-2020 - Added missing sub-key "Application"
  43. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\Application\AppUserModelId", "Chrome Portable", "REG_SZ"
  44. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\Application\ApplicationIcon", sAppPath & ",0", "REG_SZ"
  45. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\Application\ApplicationName", "Google Chrome Portable Edition", "REG_SZ"
  46. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\Application\ApplicationDescription", "Access the internet", "REG_SZ"
  47. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\Application\ApplicationCompany", "Google LLC", "REG_SZ"
  48. 'DefaultIcon
  49. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\DefaultIcon\", sAppPath & ",0", "REG_SZ"
  50. '\shell\open\command
  51. WshShell.RegWrite sbaseKey & "Classes\ChromePRHTML\shell\open\command\", sAppPath & " -- " & """" & "%1" & """", "REG_SZ"
  53. 'StartmenuInternet === 02 of kolbi.cz (https://is.gd/o5yyVp) ===
  54. '@
  55. WshShell.RegWrite sbaseKey2, "Google Chrome Portable Edition", "REG_SZ"
  56. 'Capabilities
  57. WshShell.RegWrite sbaseKey2 & "Capabilities\ApplicationDescription", "Google Chrome Portable is a web browser that runs webpages and applications.", "REG_SZ"
  58. WshShell.RegWrite sbaseKey2 & "Capabilities\ApplicationIcon", sAppPath & ",0", "REG_SZ"
  59. WshShell.RegWrite sbaseKey2 & "Capabilities\ApplicationName", "Google Chrome Portable Edition", "REG_SZ"
  60. 'FileAssociations - Eight on 3-May-2020
  61. WshShell.RegWrite sbaseKey2 & "Capabilities\FileAssociations\.htm", "ChromePRHTML", "REG_SZ"
  62. WshShell.RegWrite sbaseKey2 & "Capabilities\FileAssociations\.html", "ChromePRHTML", "REG_SZ"
  63. WshShell.RegWrite sbaseKey2 & "Capabilities\FileAssociations\.pdf", "ChromePRHTML", "REG_SZ"
  64. WshShell.RegWrite sbaseKey2 & "Capabilities\FileAssociations\.shtml", "ChromePRHTML", "REG_SZ"
  65. WshShell.RegWrite sbaseKey2 & "Capabilities\FileAssociations\.svg", "ChromePRHTML", "REG_SZ"
  66. WshShell.RegWrite sbaseKey2 & "Capabilities\FileAssociations\.webp", "ChromePRHTML", "REG_SZ"
  67. WshShell.RegWrite sbaseKey2 & "Capabilities\FileAssociations\.xht", "ChromePRHTML", "REG_SZ"
  68. WshShell.RegWrite sbaseKey2 & "Capabilities\FileAssociations\.xhtml", "ChromePRHTML", "REG_SZ"
  69. 'StartMenuInternet - 3-May-2020- Added missing sub-key "StartMenuInternet"
  70. WshShell.RegWrite sbaseKey2 & "Capabilities\Startmenu\StartMenuInternet", "Google Chrome Portable", "REG_SZ"
  71. 'URLAssociation - Thirteen on 3-May-2020
  72. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\ftp", "ChromePRHTML", "REG_SZ"
  73. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\http", "ChromePRHTML", "REG_SZ"
  74. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\https", "ChromePRHTML", "REG_SZ"
  75. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\irc", "ChromePRHTML", "REG_SZ"
  76. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\mailto", "ChromePRHTML", "REG_SZ"
  77. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\mms", "ChromePRHTML", "REG_SZ"
  78. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\news", "ChromePRHTML", "REG_SZ"
  79. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\nntp", "ChromePRHTML", "REG_SZ"
  80. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\sms", "ChromePRHTML", "REG_SZ"
  81. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\smsto", "ChromePRHTML", "REG_SZ"
  82. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\snews", "ChromePRHTML", "REG_SZ"
  83. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\tel", "ChromePRHTML", "REG_SZ"
  84. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\urn", "ChromePRHTML", "REG_SZ"
  85. WshShell.RegWrite sbaseKey2 & "Capabilities\URLAssociations\webcal", "ChromePRHTML", "REG_SZ"
  86. WshShell.RegWrite sbaseKey2 & "DefaultIcon\", sAppPath & ",0", "REG_SZ"
  87. '\shell\open\command
  88. WshShell.RegWrite sbaseKey2 & "shell\open\command\", sAppPath, "REG_SZ"
  90. 'Launch Default Apps after registering Chrome Portable
  91. 'WshShell.Run "control /name Microsoft.DefaultPrograms /page pageDefaultProgram"
  92. End Sub
  95. Sub UnregisterChromePortable(sAppPath)
  96. sbaseKey = "HKCU\Software\"
  97. sbaseKey2 = "HKCU\Software\Clients\StartmenuInternet\Google Chrome Portable"
  99. On Error Resume Next
  100. 'RegisteredApplications === 01 of kolbi.cz (https://is.gd/o5yyVp) ===
  101. WshShell.RegDelete sbaseKey & "RegisteredApplications\Google Chrome Portable"
  102. On Error GoTo 0
  104. 'Classes === 03 of kolbi.cz (https://is.gd/o5yyVp) ====
  105. WshShell.Run "reg.exe delete " & sbaseKey & "Classes\ChromePRHTML" & " /f", 0
  107. 'StartmenuInternet === 02 of kolbi.cz (https://is.gd/o5yyVp) ===
  108. 'Online research 3-May-2020, shows that getting VB script to removing REG keys is hit or miss.
  109. 'Run the VB Script with the (-REG) unregistration code along with reguler REG DELETE DOS code in a batch file.
  110. 'Below code doesn't work.
  111. 'WshShell.Run "reg.exe delete " & sbaseKey2 & " /f", 0
  113. 'Launch Default Apps after unregistering Chrome Portable
  114. 'WshShell.Run "control /name Microsoft.DefaultPrograms /page pageDefaultProgram"
  115. End Sub

Register Google Chrome Portable with Default Apps or Default Programs

For more information see https://www.winhelponline.com/blog/register-google-chrome-portable-with-default-apps-or-default-programs/