1. # Maintainer: sanbikappa <[email protected]>
  2. # Maintainer: pureboys <yuyuud@[email protected]>
  4. pkgname='kikoplay'
  5. pkgver=0.9.3
  6. pkgrel=1
  7. pkgdesc="linux danmaku player"
  8. arch=('x86_64')
  9. license=('GPL3')
  10. url="https://github.com/KikoPlayProject/KikoPlay"
  11. # using standalone liblua53.a, remove 'lua53' from depends.
  12. depends=('qt5-base' 'mpv' 'qhttpengine')
  13. makedepends=('cmake' 'git')
  14. optdepends=('aria2: for downloading')
  15. conflicts=('kikoplay-bin')
  16. source=(
  17. "https://github.com/KikoPlayProject/KikoPlay/archive/refs/tags/${pkgver}.tar.gz"
  18. "git+https://github.com/KikoPlayProject/KikoPlayScript"
  19. )
  20. sha256sums=(
  21. "96b8818450a8354ea960e1eec575830d7ed2800e90b1025ec4f9358d390e8669"
  22. SKIP
  23. )
  25. prepare() {
  26. # rename directory to "KikoPlay" to match the KikoPlay.pro file.
  27. # otherwise qmake could not find the KikoPlay.pro file.
  28. [ -d "KikoPlay" ] && rm -rf "KikoPlay"
  29. mv "${srcdir}/KikoPlay-${pkgver}" "KikoPlay"
  30. }
  32. build() {
  33. # https://github.com/KikoPlayProject/KikoPlay/issues/97#issuecomment-1427057614
  34. # compile a standalone liblua53.a, remove lua53 from depends.
  35. cmake -B"${srcdir}/build-lua53" -S"${srcdir}/KikoPlay/Script/lua"
  36. cd "${srcdir}/build-lua53"
  37. make
  38. ln -sf "${srcdir}/build-lua53/libmyLua53.a" "${srcdir}/KikoPlay/lib/x64/linux/liblua53.a"
  39. ln -sf "${srcdir}/build-lua53/libmyLua53.a" "${srcdir}/KikoPlay/Script/lua/liblua53.a"
  41. # compile kikoplay
  42. mkdir -p "${srcdir}/build"
  43. cd "${srcdir}/build"
  44. qmake "${srcdir}/KikoPlay"
  45. make
  47. ## only for test, place the "script" under the path of KikoPlay binary
  48. ## then we can test the script function without packaging or installing KikoPlay
  49. #mkdir -p "${srcdir}/build/script"
  50. #cp -r "${srcdir}"/KikoPlayScript/* "${srcdir}/build/script"
  51. }
  53. package() {
  54. cd "${srcdir}/KikoPlay"
  55. install -Dm644 KikoPlay使用说明.pdf "${pkgdir}/usr/share/doc/kikoplay/help.pdf"
  57. cd "${srcdir}/build"
  58. make install INSTALL_ROOT="${pkgdir}"
  59. ln -sf KikoPlay "${pkgdir}/usr/bin/kikoplay"
  61. # also package KikoPlay Script, but only exclude the ".git" directory
  62. install -dm755 "${pkgdir}/usr/share/kikoplay/script"
  63. cp -r "${srcdir}"/KikoPlayScript/* "${pkgdir}/usr/share/kikoplay/script"
  64. }

kikoplay archlinux PKGBUILD