1. box_height = 26.75;
  3. box_wall_thickness = 2;
  4. box_board_spacing = 0.25;
  5. box_connector_spacing = 0.25;
  7. //
  8. // Utilities
  9. //
  11. module mirror_copy(v = [1, 0, 0]) {
  12. children();
  13. mirror(v) children();
  14. }
  16. //
  17. // Board
  18. //
  20. board_thickness = 1.60;
  21. board_size = [57.0, 40.6];
  22. board_hole_dia = 3;
  23. board_hole_spacing = [52.5, 36.5];
  25. led_hole_dia = 3.0;
  26. led_standoff = 1.5;
  27. led_hole_chamfer_dia = led_hole_dia + 2.0;
  28. led_wall_thickness = box_wall_thickness / 2;
  29. led_positions = [
  30. [-board_size[0] / 2 + 20.5, 11.75],
  31. [-board_size[0] / 2 + 20.5, -11.75],
  32. [-board_size[0] / 2 + 4.5, -board_size[1] / 2 + 6.0]
  33. ];
  35. module led() {
  36. color([1, 1, 0]) linear_extrude(0.70) square([3.0, 1.25], center=true);
  37. }
  39. module board() {
  40. color([0.8, 0, 0]) translate([0, 0, -board_thickness]) linear_extrude(board_thickness) {
  41. difference() {
  42. square(board_size, center=true);
  43. mirror_copy([1, 0]) mirror_copy([0, 1])
  44. translate(board_hole_spacing / 2)
  45. circle(d=board_hole_dia, $fn=16);
  46. }
  47. }
  48. }
  50. relay_size = [18.8, 15.0, 15.5];
  51. relay_position = [board_size[0] / 2 - relay_size[0] / 2 - 8.5, relay_size[1] / 2 + 1.0];
  53. module relay() {
  54. color([0.2, 0.4, 0.9])
  55. translate([-relay_size[0]/2, -relay_size[1]/2, 0])
  56. cube(relay_size);
  57. }
  59. usb_connector_size = [16.5, 12.3, 11.0];
  60. usb_connector_overhang = 6.0;
  61. usb_connector_position = [-board_size[0] / 2 + usb_connector_size[0] / 2 - usb_connector_overhang, 0];
  63. module usb_connector() {
  64. color([0.75, 0.75, 0.75])
  65. translate([-usb_connector_size[0]/2, -usb_connector_size[1]/2, 0])
  66. cube(usb_connector_size);
  67. }
  69. terminal_block_size = [7.5, 15];
  70. terminal_block_height = 10.0;
  71. terminal_block_spacing = 1.5;
  72. terminal_block_total_width = terminal_block_size[1] * 2 + terminal_block_spacing;
  73. terminal_block_position = [board_size[0] / 2 - terminal_block_size[0] / 2,
  74. -terminal_block_size[1] / 2 - terminal_block_spacing / 2];
  76. module terminal_block() {
  77. color([0.3, 0.8, 0.2])
  78. translate(-terminal_block_size/2) rotate([0, -90, -90]) linear_extrude(15.0)
  79. polygon([[0, 0], [7.0, 0], [10.0, 2.0], [10.0, 6.5], [7.0, 7.5], [0.0, 7.5]]);
  80. }
  82. module board_assembly() {
  83. board();
  84. mirror_copy([0, 1, 0]) translate(relay_position) relay();
  85. translate(usb_connector_position) usb_connector();
  86. mirror_copy([0, 1, 0]) translate(terminal_block_position) terminal_block();
  87. for (p=led_positions) translate(p) led();
  88. }
  90. //
  91. // Common
  92. //
  94. box_hole_dia = 3.2;
  95. screw_head_dia = 5.7;
  96. screw_head_height = 1.8;
  98. box_inside_width = board_size[1] + box_board_spacing * 2;
  100. module box_inside() {
  101. translate([-board_size[0] / 2 - usb_connector_overhang + box_wall_thickness,
  102. -box_inside_width / 2])
  103. square([board_size[0] + usb_connector_overhang - box_wall_thickness + box_board_spacing,
  104. box_inside_width]);
  105. }
  107. terminal_block_cutout_width = terminal_block_total_width + box_connector_spacing * 2;
  108. terminal_block_cotout_start = terminal_block_position[0] - terminal_block_size[0] / 2 + 2;
  110. module connector_cutouts() {
  111. translate([0, 0, -box_connector_spacing])
  112. linear_extrude(usb_connector_size[2] + box_connector_spacing * 2)
  113. translate([-100, -usb_connector_size[1]/2 - box_connector_spacing])
  114. square([100, usb_connector_size[1] + box_connector_spacing * 2]);
  115. translate([terminal_block_cotout_start, 0, -box_connector_spacing])
  116. linear_extrude(100)
  117. translate([0, -terminal_block_cutout_width/2])
  118. square([100, terminal_block_cutout_width]);
  119. }
  121. module back_pillars() {
  122. mirror([1, 0]) mirror_copy([0, 1])
  123. translate(board_hole_spacing / 2)
  124. children();
  125. }
  127. module pillars() {
  128. mirror_copy([1, 0]) back_pillars() children();
  129. }
  131. //
  132. // Bottom
  133. //
  135. bottom_height = 7.0;
  136. box_lip_height = 2.0;
  137. box_lip_offset = 0.1;
  138. box_base_thickness = 3.0;
  140. bottom_pillar_width = box_inside_width - board_hole_spacing[1];
  142. nut_dia = 5.6 / cos(30);
  143. nut_thickness = 2.5;
  145. module bottom() {
  146. render() difference() {
  147. union() {
  148. difference() {
  149. translate([0, 0, -bottom_height])
  150. linear_extrude(bottom_height + box_lip_height)
  151. offset(box_wall_thickness, $fn=32)
  152. box_inside();
  153. linear_extrude(100)
  154. offset(box_wall_thickness / 2 + box_lip_offset, $fn=16)
  155. box_inside();
  156. translate([0, 0, -bottom_height + box_base_thickness])
  157. linear_extrude(100)
  158. box_inside();
  159. }
  160. translate([0, 0, -bottom_height]) linear_extrude(bottom_height - board_thickness)
  161. pillars() offset(box_wall_thickness / 2, $fn=32)
  162. square([bottom_pillar_width, bottom_pillar_width], center=true);
  163. }
  164. connector_cutouts();
  165. translate([0, 0, -100]) linear_extrude(100) pillars() circle(d=box_hole_dia, $fn=32);
  166. translate([0, 0, -bottom_height]) linear_extrude(nut_thickness) pillars() circle(d=nut_dia, $fn=6);
  167. }
  168. }
  170. //
  171. // Top
  172. //
  174. text_spacing = 5;
  175. text_depth = 0.5;
  176. text_height = 2.5;
  177. text_label_offset = 10;
  179. module relay_label(label) {
  180. rotate([0, 0, 180]) union() {
  181. translate([text_label_offset, 0, 0]) text(label, text_height * 2, font="Arial", valign="center");
  182. translate([0, -text_spacing, 0]) text("NC", text_height, font="Arial", valign="center");
  183. text("COM", text_height, font="Arial", valign="center");
  184. translate([0, text_spacing, 0]) text("NO", text_height, font="Arial", valign="center");
  185. }
  186. }
  188. module labels() {
  189. translate([terminal_block_cotout_start - 2.0, terminal_block_position[1]]) relay_label("1");
  190. translate([terminal_block_cotout_start - 2.0, -terminal_block_position[1]]) relay_label("2");
  191. }
  193. top_height = box_height - bottom_height;
  194. top_pillar_width = box_hole_dia;
  196. module top() {
  197. render() difference() {
  198. union() {
  199. difference() {
  200. minkowski($fn=32) {
  201. linear_extrude(top_height - box_wall_thickness) box_inside();
  202. sphere(box_wall_thickness);
  203. }
  204. linear_extrude(top_height - box_wall_thickness) box_inside();
  205. connector_cutouts();
  206. translate([-50, -50, -100]) cube([100, 100, 100]);
  207. }
  208. mirror_copy([0, 1, 0])
  209. translate([terminal_block_cotout_start - 2.0, terminal_block_cutout_width / 2, 0])
  210. linear_extrude(top_height - box_wall_thickness)
  211. square([
  212. board_size[0] / 2 + box_board_spacing + box_wall_thickness - terminal_block_cotout_start,
  213. (box_inside_width - terminal_block_cutout_width) / 2]);
  214. linear_extrude(top_height - box_wall_thickness)
  215. back_pillars() offset(box_wall_thickness / 2, $fn=32)
  216. translate([-top_pillar_width/2, -top_pillar_width/2])
  217. square([top_pillar_width, top_pillar_width/2 + (box_inside_width - board_hole_spacing[1]) / 2]);
  218. translate([terminal_block_cotout_start, box_inside_width / 2, 0])
  219. rotate([90, 0, 0]) linear_extrude(box_inside_width)
  220. polygon([
  221. [-2.0, terminal_block_height + box_connector_spacing - 3.0],
  222. [-2.0, top_height],
  223. [0.0, top_height],
  224. [0.0, terminal_block_height + box_connector_spacing]]);
  226. for (p=led_positions) {
  227. translate([0, 0, led_standoff])
  228. translate(p) linear_extrude(top_height - led_standoff - box_wall_thickness)
  229. circle(d=led_hole_dia + led_wall_thickness * 2, $fn=32);
  230. }
  232. }
  233. linear_extrude(100) pillars() circle(d=box_hole_dia, $fn=32);
  234. translate([0, 0, top_height - screw_head_height])
  235. linear_extrude(100) pillars() circle(d=screw_head_dia, $fn=32);
  236. difference() {
  237. linear_extrude(box_lip_height) offset(100, $fn=4) box_inside();
  238. linear_extrude(100) offset(box_wall_thickness / 2 + box_lip_offset, $fn=32)
  239. box_inside();
  240. }
  242. translate([0, 0, top_height - text_depth]) linear_extrude(100) labels();
  244. for (p=led_positions) {
  245. translate(p) linear_extrude(100) circle(d=led_hole_dia, $fn=16);
  246. translate([0, 0, top_height - led_hole_chamfer_dia/2])
  247. translate(p) cylinder(h=led_hole_chamfer_dia/2, r1=0, r2=led_hole_chamfer_dia/2, $fn=32);
  248. }
  249. }
  250. }
  252. board_assembly();
  253. bottom();
  254. top();